home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
BBS Toolkit
/
BBS Toolkit.iso
/
qbbs
/
zlab_ra3.zip
/
ZLAB-EFT.BAT
< prev
next >
Wrap
DOS Batch File
|
1992-02-08
|
2KB
|
44 lines
@echo off
rem ZipLab Plus - EFT Interface batch
rem by Mike Ehlert 1:102/1001
rem Version 2.0
rem
rem Read the ZLAB-RA.DOC that came with this batch for more info.
rem
rem This will assume the enviornment variable %NODE% is set to the current
rem node number. For example "Set NODE=1" for line1, and so on.
rem If you don't run multinode, then you can replace "%NODE%" with "1"
rem
rem
rem First convert the RA DORINFO1.DEF to PCBOARD.DAT and PCBOARD.SYS files
rem and add on lines 153-198 to make it an extended PCBOARD.DAT
qkdoor c:\ra\line%NODE%\RA c:\ra\line%NODE%\PCB14
copy c:\ra\line%NODE%\pcboard.dat+c:\ra\ziplab\add.%NODE% c:\ra\line%NODE%\pcboard.dat
rem The next rem will create a 0 byte caller file, expected by ziplab
rem>c:\ra\line%NODE%\caller
rem The set statment will make ZipLab think we are running Prodoor,
rem so that ZipLab will not look for extra pcb files.
set PCBDOOR=PRODOOR
Rem Run Ziplab Plus (ptest) and pass it the filename and .cfg file to use.
c:\ra\ziplab\ptest.exe %1 c:\ra\ziplab\ptest%NODE%.cfg
rem If a file call PCBFAIL.TXT exists, that means that ziplab considers
rem the test to have failed. EFT does not care about such a filename,
rem EFT only checks if a file called GOOD exists, then the test passed.
rem So here we must create GOOD as long as there is no PCBFAIL.TXT.
if exist c:\ra\line%NODE%\pcbfail.txt goto bad
echo good > GOOD
goto end
:bad
erase c:\ra\line%NODE%\pcbfail.txt
rem since a file failed, add the reason and uploders name to the ziplab.log
copy c:\ra\ziplab\ziplab.log+c:\ra\line%NODE%\caller+exitinfo.eft c:\ra\ziplab\ziplab.log
:end
Rem Thats it, now its back to EFT.